// outline_sort v1.01 peter@TurtleCoveTech.com
//
// Sorts an outline.
// Treats the selection or the buffer as an indented outline and sorts
// based on the leftmost indented "parents", carrying the subtrees with their
// respective parents.
//
// Skips lines with jEdit auto-settings :setting=value: at the top or bottom
// of the file.
//
// I keep all of my info in plain text outlines (Org-Mode style) and this allows me to sort my outlines.
// Note: I bind this to 'CS+O s' (the two letter code Control-Shift-O s). I plan on writing more Outline macros in the style of Org-Mode and binding them to (refile: CS+O r, sort: CS+O s, capture: CS+O c, SearchToSparseTree: SC+O f, archive: CS+O a, etc)
// Handy Tip: hit 'control-e s' to select a tree before sorting to sort just one outline tree instead of the entire buffer.



import java.util.TreeMap;
JEditBuffer buffer=textArea.getBuffer();
tabwidth=buffer.getTabSize();
DEBUG=false;

int get_indent(line) {
	line_notabs=TextUtilities.tabsToSpaces( line, tabwidth);
	line_indent=0;
	while( line_indent<line_notabs.length() && line_notabs.charAt(line_indent)==' ') {
		line_indent++;
	}
	return line_indent;
}
	
void outline_sort() {
	
	Selection[] selections=textArea.getSelection();
	
	// get the start and end lines (ignore multiple selections)
	buffer_end=buffer.getLineCount()-1;
	if (selections.length==0) {
		start_line=0;
		end_line=buffer_end;
	} else {
		start_line=selections[0].getStartLine();
		end_line=selections[0].getEndLine();
	}
	if (DEBUG) Macros.message(view, "Sorting from line "+start_line+" to "+end_line);
	// scan through the text, find the leftmost entries
	// which are the sortable 'parents' in the outline
	//
	// also skip header lines with jEdit auto-settings :setting=value:
	// skip footer lines with jEdit auto-settings :setting=value:
	// skip any initial lines that may be selected by mistake and only
	// include SOME of an outline, but not the parent
	
	// find the top level indent level, and find headers and footers
	in_header=true;
	in_footer=false;
	first_sortable=-1;
	last_line=end_line;
	int indent;
	int min_indent=9999;
	
	// Find left-most indent:
	for(int i=start_line;i<=end_line;i++) {
		line=buffer.getLineText(i);
		if (line.matches("^[ \t]*$")) // skip blank lines
			continue;
		// try to find and skip headers and footers
		// with jEdit auto-settings :setting=value:
		if (in_header && line.matches(".*:\\w+=.*:.*"))
			continue; // try to skip jEdit auto-settings
		if (in_header)
			in_header=false;
		if (!in_footer && line.matches(".*:\\w+=.*:.*")) {
			in_footer=true;
			last_line=i-1;
		}
		if (in_footer && !line.matches(".*:\\w+=.*:.*")) {
			in_footer=false;
			last_line=end_line;
		}
		// calc left-most indent
		indent=get_indent(buffer.getLineText(i));
		if (indent<min_indent) {
			min_indent=indent;
			first_sortable=i;
		}
	}
	if (DEBUG) Macros.message(view, "Sortable body from line "+first_sortable+" to "+last_line+" at indent "+min_indent);
	
	//
	// gather sorting lines and sort them by putting them into
	// a sorted data structure
	TreeMap sortable=new TreeMap();
	for(int i=first_sortable;i<=last_line;i++) {
		line=buffer.getLineText(i);
		if (line.matches("^[ \t]*$"))
			continue; // skip blanks
		indent=get_indent(line);
		if (indent==min_indent) {
			sortable.put(line, i);
		}
	}
	if (DEBUG) Macros.message(view, "Sorted header lines="+sortable.keySet());
	
	// Get sorted results
	StringBuffer results=new StringBuffer();
	// first copy header and pre-outline lines
	for(int i=start_line; i<first_sortable; i++) {
		results.append( buffer.getLineText(i)+"\n");
	}
	// then copy sorted outlines
	for( int i : sortable.values() ) { // for each parent
		// copy the subtree up to the next parent
		j=i;
		line=buffer.getLineText(j);
		indent=get_indent(line);
		do {
			results.append( line);
			if (j!=buffer_end) results.append( "\n");
			j++;
			if (j<=end_line) {
				line=buffer.getLineText(j);
				indent=get_indent(line);
			}
			
		} while ( j<=last_line && (indent!=min_indent || line.matches("^[ \t]*$")));
	}
	// finally copy the footers
	for(int i=last_line+1; i<=end_line; i++) {
		results.append( buffer.getLineText(i));
		if (i!=buffer_end) results.append("\n");
	}
		
	// replace the buffer or selection with the results
	if (DEBUG) Macros.message(view, "Result length="+results.length()+", replacing buffer length="+buffer.getLength());
	start_offset = buffer.getLineStartOffset( start_line);
	buffer.remove( start_offset, results.length());
	buffer.insert( start_offset, results.toString());

}


if (buffer.isReadOnly())
	Macros.error(view, "Buffer is read-only.");
else
	outline_sort();


/*
	Macro index data (in DocBook format)

<listitem>
	<para><filename>outline_sort.bsh</filename></para>
	<abstract><para>
	Sorts buffer or selection as an outline, preserving subtrees.
	</para></abstract>
</listitem>

*/